package {
    import flash.display.*;
    import flash.events.*;
    import flash.filters.BlurFilter;
    import flash.geom.*;
    import flash.media.*;
    import flash.net.*;
    import flash.utils.ByteArray;

    import org.papervision3d.core.effects.BitmapLayerEffect;
    import org.papervision3d.core.effects.utils.BitmapClearMode;
    import org.papervision3d.core.effects.utils.BitmapDrawCommand;

    
    import org.papervision3d.objects.primitives.Plane;

    import org.papervision3d.view.layer.BitmapEffectLayer;

    import org.papervision3d.cameras.*;
    import org.papervision3d.core.proto.*;
    import org.papervision3d.core.render.data.*;
    import org.papervision3d.events.*;
    import org.papervision3d.materials.*;
    
    import org.papervision3d.render.*;
    import org.papervision3d.scenes.*;
    import org.papervision3d.view.*;

    import org.papervision3d.objects.*;

    public class sample04 extends Sprite {

        private const WW:Number=320;
        private const HH:Number=240;
        private const PLANE_N:int=60;

        private var planeArray:Array;
        private var sound:Sound;
        private var bytes:ByteArray;
        private var spectrum:Array;


        private var space:DisplayObject3D;
        public var scene:Scene3D;
        public var renderer:BasicRenderEngine;
        public var camera:Camera3D;
        public var camera_shadow:Camera3D;
        public var viewport:Viewport3D;



        // コンストラクタ
        public function sample04() {
            // ステージの設定
            stage.scaleMode=StageScaleMode.NO_SCALE;
            stage.align=StageAlign.TOP_LEFT;
            //stage.quality=StageQuality.HIGH;
            stage.frameRate=25;

            sound = new Sound();
            sound.load(new URLRequest("MySound.mp3"));
            sound.play();
            // スペクトラム用の配列を初期化
            bytes=new ByteArray();
            spectrum = new Array();

            init3D();
            onInit();
        }
        private function init3D():void {

            scene= new Scene3D();
            renderer= new BasicRenderEngine();
            camera= new Camera3D();
            viewport = new Viewport3D(640,480,true);
            this.addChild(viewport);

            space = scene.addChild(new DisplayObject3D());
        }

        // 初期化を行う関数
        private function onInit():void {

            // Planeの設置
            var layer:BitmapEffectLayer=new BitmapEffectLayer(viewport, WW * 2, HH * 2, true, 0, BitmapClearMode.CLEAR_PRE, true);
            layer.addEffect(new BitmapLayerEffect(new BlurFilter(7, 7, 4), false));
            layer.drawCommand=new BitmapDrawCommand(null, new ColorTransform(1, 1, 1, 0.25), BlendMode.ADD);
            layer.drawLayer.blendMode=BlendMode.OVERLAY;
            layer.clippingPoint = new Point(0, -1);

            viewport.containerSprite.addLayer(layer);


            planeArray=[];
            for (var i:int=0; i < PLANE_N; i++) {
                var r:int=200;
                var mat:ColorMaterial=new ColorMaterial(HSBtoRGB(i / PLANE_N, 1, 1), 1, true);
                var p:Plane=new Plane(mat, 100, 3);
                p.material.doubleSided=true;

                space.addChild(p);
                planeArray[i] = p;

                p.x=r * Math.cos(360 / PLANE_N * i * Math.PI / 180);
                p.y=r * Math.sin(360 / PLANE_N * i * Math.PI / 180);
                p.rotationY = 90;

                //trace(p)
                layer.addDisplayObject3D(p);
            }
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            stage.addEventListener(Event.RESIZE, onResize);
        }

        // リサイズイベント用関数
        private function onResize(e:Event):void {
            viewport.x=(stage.stageWidth - WW * 2) * 0.5 - 4;
            viewport.y=(stage.stageHeight - HH * 2) * 0.5;
        }

        // エンターフレームイベント用関数
        private function onEnterFrame(e:Event):void {
            space.yaw(1);
            space.pitch(1);
            // スペクトラムの処理
            SoundMixer.computeSpectrum(bytes, true, 0);
            var i:int;
            for (i = 0; i < 256; i++) {
                spectrum[i] = bytes.readFloat();
                for (var j=0; j < PLANE_N; j++) {
                    var p:Plane = planeArray[j]as Plane;
                    p.scaleX = 1 + 20 * spectrum[Math.floor(256 / PLANE_N * j)];
                    p.rotationZ -= 0.5;
                }
            }
            renderer.renderScene(scene,camera,viewport);
        }

        // HSB -> RGBの変換
        private function HSBtoRGB(hue:Number, saturation:Number, brightness:Number):uint {
            var r:int=0;
            var g:int=0;
            var b:int=0;
            if (saturation == 0) {
                r=g=b=brightness * 255.0 + 0.5;
            } else {
                var h:Number=(hue - Math.floor(hue)) * 6.0;
                var f:Number=h - Math.floor(h);
                var p:Number=brightness * (1.0 - saturation);
                var q:Number=brightness * (1.0 - saturation * f);
                var t:Number=brightness * (1.0 - (saturation * (1.0 - f)));
                switch (int(h)) {
                    case 0 :
                        r=brightness * 255.0 + 0.5;
                        g=t * 255.0 + 0.5;
                        b=p * 255.0 + 0.5;
                        break;
                    case 1 :
                        r=q * 255.0 + 0.5;
                        g=brightness * 255.0 + 0.5;
                        b=p * 255.0 + 0.5;
                        break;
                    case 2 :
                        r=p * 255.0 + 0.5;
                        g=brightness * 255.0 + 0.5;
                        b=t * 255.0 + 0.5;
                        break;
                    case 3 :
                        r=p * 255.0 + 0.5;
                        g=q * 255.0 + 0.5;
                        b=brightness * 255.0 + 0.5;
                        break;
                    case 4 :
                        r=t * 255.0 + 0.5;
                        g=p * 255.0 + 0.5;
                        b=brightness * 255.0 + 0.5;
                        break;
                    case 5 :
                        r=brightness * 255.0 + 0.5;
                        g=p * 255.0 + 0.5;
                        b=q * 255.0 + 0.5;
                        break;
                }
            }
            return r << 16 | g << 8 | b << 0;
        }

    }
}